插入项目符号列表和图片

本示例使用 VBA 在活动演示文稿的第一张幻灯片中创建一个项目符号列表，并将项目符号样式设置为彩色阴影数字，其背景为具有普通文本颜色的圆形背景，复制此项目列表并调整其位置，最后将本地硬盘中的图片添加到当前幻灯片的右下角。

示例代码

Sub BulletsPics()
    Dim btext, it, act As Presentation, sc As Integer, pic As Shape
    Set act = ActivePresentation
    btext = Array("文本一", "文本二", "文本三", "文本四") ' 项目列表文本
    
    '以下代码在第一张幻灯片中操作
    With act.Slides(1)
        '插入项目列表
        With .Shapes.AddTextbox(msoTextOrientationHorizontal, 100, 100, 400, 200)
            With .TextFrame
                .WordWrap = msoTrue
                With .TextRange
                    .Paragraphs(Start:=1, Length:=1).ParagraphFormat.Bullet.Visible = -1
                    For Each it In btext
                        .Text = .Text & it & vbCr
                    Next
                End With
            End With
        End With
        
        '设置项目列表格式
        sc = .Shapes.Count
        With .Shapes(sc).TextFrame.TextRange
            .Font.Size = 30
            .ParagraphFormat.Bullet.Style = ppBulletCircleNumWDBlackPlain
        End With
        
        .Shapes(sc).Copy    ' 复制项目列表
        .Shapes.Paste       ' 粘贴项目列表
        
        '设置粘贴的项目列表位置
        .Shapes(sc + 1).Top = .Shapes(sc).Top
        .Shapes(sc + 1).Left = .Shapes(sc).Left + act.PageSetup.SlideWidth / 4
        
        '插入本地图片,请更改图片路径
        With .Shapes.AddPicture("D:\Demo\demo.png", msoFalse, msoTrue, 600, 300)
            .LockAspectRatio = True '锁定长宽比例
            .Width = act.PageSetup.SlideWidth / 4   '图片宽度为幻灯片页面宽度的1/4
        End With
        
    End With
End Sub

演示效果如下：