设置单元格批注

在 Excel VBA 中，您可以使用 Range 对象的 AddComment 方法为单元格添加批注。

添加批注

以下示例在单元格 A1 添加一个批注，批注内容为 "Excel VBA 教程"，且隐藏批注。

Sub AddCommentToCell()
    Dim cell As Range
    
    ' 设置要添加批注的单元格
    Set cell = Range("A1")
    
    ' 检查单元格是否已有批注，如果没有则添加批注
    If cell.Comment Is Nothing Then
        
        ' 添加新的批注
        cell.AddComment "Excel VBA 教程"
        
        ' 设置批注的可见性为隐藏
        cell.Comment.Visible = False
    End If
End Sub

编辑批注

使用 Comment 对象的 Text 方法，能够获取或修改单元格批注的文本。

Sub EditComment()
    ' 设置要修改批注的单元格
    With Range("A2")
        ' 检查单元格是否已有批注，如果有则
        If Not .Comment Is Nothing Then
            ' 在对话框中显示批注内容
            MsgBox .Comment.Text
            ' 更改批注内容
            .Comment.Text Text:="果果云课堂"
        End If
    End With
End Sub

Comment.Text 方法

语法

Comment.Text (Text, Start, Overwrite)

返回值

String

示例

以下示例代码将单元格 A2 的批注文本另起一行再添加 A2 单元格中的内容到批注文本。

Sub CommentText()
    With Range("A2").Comment
        .Text Text:=VBA.vbCrLf & Range("A2").Value, Start:=Len(.Text) + 1
    End With
End Sub

修改批注外观

在默认情况下，批注的外观是一个矩形框，Comment.Shape 属性返回一个 Shape 对象，该对象代表附加到指定批注的形状，通过设置 Shape 对象的 AutoShapeType 属性可以修改批注的外观。

以下示例代码将单元格 A2 的批注外观改为一个圆角矩形：

Sub ChangeCommentShapeType()
    Range("A2").Comment.Shape.AutoShapeType = msoShapeRoundedRectangle
End Sub

以下示例代码将单元格 A2 的批注外观恢复为一个直角矩形：

Sub RestoreCommentShapeType()
    Range("A2").Comment.Shape.AutoShapeType = 1 'msoShapeRectangle
End Sub

MsoAutoShapeType 常量

MsoAutoShapeType 常量指定 AutoShape 对象的形状类型。

添加图片批注

我们还可以为单元格批注添加背景图片或者直接将图片作为批注的内容。

以下示例代码如下将当前工作簿所在文件夹中的图片“Panda.jpg”作为单元格 A2 批注的背景图片。

Sub FillCommentPictureShape()
    With Range("A2").Comment
        .Shape.Fill.UserPicture ThisWorkbook.path & "\Panda.jpg"
    End With
End Sub

Shape 对象的 Fill 属性能够返回 FillFormat 对象，该对象包含指定的图表或图形的填充格式属性，FillFormat 对象的 UserPicture 方法为形状填充图像，其语法格式如下：

UserPicture (PictureFile)

其中，参数 PictureFile 指定要填充的图片文件的文件路径，或者图片文件的名称（如果当前存在指向图片文件的链接）。

清除批注填充

以下代码清除单元格 A2 中的批注填充效果，保留文字填充：

Sub ClearCellCommentFill()
    With Range("A2").Comment
        ' 清除批注的填充
        .Shape.Fill.Visible = msoFalse
    End With
End Sub

设置批注字体

通过单元格批注的 Shape 对象中的 TextFrame 对象（文本框对象）的 Characters 对象（字符对象）进行批注的字体设置。

以下示例代码设置活动工作表中所有批注的字符格式，字体为仿宋，加粗，字号为14号，字体颜色为黑色：

Sub CommentFont()
    Dim objComment As Comment
    For Each objComment In ActiveSheet.Comments
        With objComment.Shape.TextFrame.Characters.Font
            .Name = "仿宋"  ' 设置字体为仿宋
            .Bold = True  ' 设置字体为粗体
            .Size = 14  ' 设置字号为14
            .Color = RGB(0, 0, 0) ' 设置字体颜色为黑色
        End With
    Next objComment
    Set objComment = Nothing
End Sub